diff --git a/acinclude.m4 b/acinclude.m4
new file mode 100644
index 0000000000..fa8fef25f7
--- /dev/null
+++ b/acinclude.m4
@@ -0,0 +1,39 @@
+dnl
+dnl local autoconf/automake macros needed for heartbeat
+dnl	Started by David Lee <t.d.lee@durham.ac.uk> February 2006
+dnl
+dnl License: GNU General Public License (GPL)
+
+
+dnl AM_CHECK_PYTHON_HEADERS:  Find location of python include files.
+dnl Taken from:
+dnl	http://source.macgimp.org/
+dnl which is GPL and is attributed to James Henstridge.
+dnl
+dnl AM_CHECK_PYTHON_HEADERS([ACTION-IF-POSSIBLE], [ACTION-IF-NOT-POSSIBLE])
+dnl Imports:
+dnl	$PYTHON
+dnl Exports:
+dnl	PYTHON_INCLUDES
+
+AC_DEFUN([AM_CHECK_PYTHON_HEADERS],
+[AC_REQUIRE([AM_PATH_PYTHON])
+AC_MSG_CHECKING(for headers required to compile python extensions)
+dnl deduce PYTHON_INCLUDES
+py_prefix=`$PYTHON -c "import sys; print sys.prefix"`
+py_exec_prefix=`$PYTHON -c "import sys; print sys.exec_prefix"`
+PYTHON_INCLUDES="-I${py_prefix}/include/python${PYTHON_VERSION}"
+if test "$py_prefix" != "$py_exec_prefix"; then
+  PYTHON_INCLUDES="$PYTHON_INCLUDES -I${py_exec_prefix}/include/python${PYTHON_VERSION}"
+fi
+AC_SUBST(PYTHON_INCLUDES)
+dnl check if the headers exist:
+save_CPPFLAGS="$CPPFLAGS"
+CPPFLAGS="$CPPFLAGS $PYTHON_INCLUDES"
+AC_TRY_CPP([#include <Python.h>],dnl
+[AC_MSG_RESULT(found)
+$1],dnl
+[AC_MSG_RESULT(not found)
+$2])
+CPPFLAGS="$save_CPPFLAGS"
+])