diff --git a/cts/schemas/test-3/ref.err/nagios.ref.err-4 b/cts/schemas/test-3/ref.err/nagios.ref.err-4
index e69de29bb2..b32b425829 100644
--- a/cts/schemas/test-3/ref.err/nagios.ref.err-4
+++ b/cts/schemas/test-3/ref.err/nagios.ref.err-4
@@ -0,0 +1,8 @@
+WARNING: Dropping template template_drop because nagios resources are no longer supported
+WARNING: Dropping resource primitive1_drop because nagios resources are no longer supported
+WARNING: Dropping resource primitive3_drop because nagios resources are no longer supported
+WARNING: Dropping resource grp2_rsc1_drop because nagios resources are no longer supported
+WARNING: Dropping resource grp2_rsc3_drop because nagios resources are no longer supported
+WARNING: Dropping resource clone4_grp_rsc1_drop because nagios resources are no longer supported
+WARNING: Dropping resource clone4_grp_rsc3_drop because nagios resources are no longer supported
+WARNING: Dropping resource bundle_rsc_drop because nagios resources are no longer supported
diff --git a/cts/schemas/test-3/ref.err/upstart.ref.err-4 b/cts/schemas/test-3/ref.err/upstart.ref.err-4
index e69de29bb2..635425a873 100644
--- a/cts/schemas/test-3/ref.err/upstart.ref.err-4
+++ b/cts/schemas/test-3/ref.err/upstart.ref.err-4
@@ -0,0 +1,8 @@
+WARNING: Dropping template template_drop because upstart resources are no longer supported
+WARNING: Dropping resource primitive1_drop because upstart resources are no longer supported
+WARNING: Dropping resource primitive3_drop because upstart resources are no longer supported
+WARNING: Dropping resource grp2_rsc1_drop because upstart resources are no longer supported
+WARNING: Dropping resource grp2_rsc3_drop because upstart resources are no longer supported
+WARNING: Dropping resource clone4_grp_rsc1_drop because upstart resources are no longer supported
+WARNING: Dropping resource clone4_grp_rsc3_drop because upstart resources are no longer supported
+WARNING: Dropping resource bundle_rsc_drop because upstart resources are no longer supported
diff --git a/xml/upgrade-3.10-4.xsl b/xml/upgrade-3.10-4.xsl
index d69f669ff8..251ab58eeb 100644
--- a/xml/upgrade-3.10-4.xsl
+++ b/xml/upgrade-3.10-4.xsl
@@ -1,193 +1,221 @@
 <?xml version="1.0" encoding="UTF-8"?>
 
 <!--
  Use comments liberally as future maintainers may be unfamiliar with XSLT.
  -->
 
 <!--
  upgrade-3.10-4.xsl
 
  Guarantees after this transformation:
  * There are no nagios-class or upstart-class resources. If there were any prior
    to this transformation, they have been dropped.
  * There are no bundle resources based on rkt containers. If there were any
    prior to this transformation, they have been dropped.
  * The restart-type resource meta-attribute is not present.
  * The can_fail operation meta-attribute is not present.
  * The role_after_failure operation meta-attribute is not present.
  -->
 
 <xsl:stylesheet version="1.0"
                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
 <xsl:import href="upgrade-3.10-common.xsl"/>
 
 <!-- XSLT 1.0 lacks upper-case() and lower-case() functions -->
 <xsl:variable name="upper" select="'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
 <xsl:variable name="lower" select="'abcdefghijklmnopqrstuvwxyz'"/>
 
 <!-- Index all resource templates by ID -->
 <xsl:key name="template_id" match="template" use="@id"/>
 
 <!-- Copy everything unaltered by default -->
 <xsl:template match="/|@*|node()">
     <xsl:call-template name="identity"/>
 </xsl:template>
 
 
 <!-- Resources -->
 
 <!-- The following XSL templates use XPath 1.0 set intersection idioms -->
 
 <!-- Upstart-class templates -->
 <xsl:variable name="dropped_templates"
               select="//template
                       [(translate(@class, $upper, $lower) = 'nagios')
                        or (translate(@class, $upper, $lower) = 'upstart')]"/>
 
 <!-- Upstart-class primitives -->
 <xsl:variable name="dropped_primitives"
               select="//primitive
                       [(translate(@class, $upper, $lower) = 'nagios')
                        or (translate(@class, $upper, $lower) = 'upstart')
                        or (@template
                            and (count(key('template_id', @template)
                                       |$dropped_templates)
                                 = count($dropped_templates)))]"/>
 
 <!-- Groups containing only nagios- and upstart-class primitives -->
 <xsl:variable name="dropped_groups"
               select="//group[count(primitive|$dropped_primitives)
                               = count($dropped_primitives)]"/>
 
 <!-- Clones containing only nagios- and upstart-class primitives -->
 <xsl:variable name="dropped_clones"
               select="//clone[count(.//primitive|$dropped_primitives)
                               = count($dropped_primitives)]"/>
 
 <!-- All dropped resources -->
 <xsl:variable name="dropped_resources"
               select="$dropped_primitives
                       |$dropped_groups
                       |$dropped_clones
                       |//bundle[rkt]"/>
 
 <!-- Drop nagios- and upstart-class resource templates -->
 <xsl:template match="template">
-    <xsl:if test="count(.|$dropped_templates) != count($dropped_templates)">
-        <xsl:call-template name="identity"/>
-    </xsl:if>
+    <xsl:choose>
+        <xsl:when test="count(.|$dropped_templates)
+                        = count($dropped_templates)">
+            <xsl:call-template name="warning">
+                <xsl:with-param name="msg"
+                                select="concat('Dropping template ', @id,
+                                               ' because ', @class,
+                                               ' resources are no longer',
+                                               ' supported')"/>
+            </xsl:call-template>
+        </xsl:when>
+
+        <xsl:otherwise>
+            <xsl:call-template name="identity"/>
+        </xsl:otherwise>
+    </xsl:choose>
 </xsl:template>
 
 <!-- Drop nagios- and upstart-class primitives -->
 <xsl:template match="primitive">
-    <xsl:if test="count(.|$dropped_primitives) != count($dropped_primitives)">
-        <xsl:call-template name="identity"/>
-    </xsl:if>
+    <xsl:choose>
+        <xsl:when test="count(.|$dropped_primitives)
+                        = count($dropped_primitives)">
+            <xsl:variable name="class"
+                          select="@class|key('template_id', @template)/@class"/>
+            <xsl:call-template name="warning">
+                <xsl:with-param name="msg"
+                                select="concat('Dropping resource ', @id,
+                                               ' because ', $class,
+                                               ' resources are no longer',
+                                               ' supported')"/>
+            </xsl:call-template>
+        </xsl:when>
+
+        <xsl:otherwise>
+            <xsl:call-template name="identity"/>
+        </xsl:otherwise>
+    </xsl:choose>
 </xsl:template>
 
 <!-- Drop groups that would become empty -->
 <xsl:template match="group">
     <xsl:if test="count(.|$dropped_groups) != count($dropped_groups)">
         <xsl:call-template name="identity"/>
     </xsl:if>
 </xsl:template>
 
 <!-- Drop clones that would become empty -->
 <xsl:template match="clone">
     <xsl:if test="count(.|$dropped_clones) != count($dropped_clones)">
         <xsl:call-template name="identity"/>
     </xsl:if>
 </xsl:template>
 
 <!-- Drop rkt bundles -->
 <xsl:template match="bundle[rkt]"/>
 
 <!-- Drop restart-type resource meta-attribute -->
 <xsl:template match="template/meta_attributes/nvpair[@name = 'restart-type']
                      |primitive/meta_attributes/nvpair[@name = 'restart-type']
                      |group/meta_attributes/nvpair[@name = 'restart-type']
                      |clone/meta_attributes/nvpair[@name = 'restart-type']
                      |bundle/meta_attributes/nvpair[@name = 'restart-type']
                      |rsc_defaults/meta_attributes/nvpair
                          [@name = 'restart-type']"/>
 
 <!-- Drop can_fail operation meta-attribute -->
 <xsl:template match="op/meta_attributes/nvpair[@name = 'can_fail']
                      |op_defaults/meta_attributes/nvpair[@name = 'can_fail']"/>
 
 <!-- Drop role_after_failure operation meta-attribute -->
 <xsl:template match="op/meta_attributes/nvpair[@name = 'role_after_failure']
                      |op_defaults/meta_attributes/nvpair
                          [@name = 'role_after_failure']"/>
 
 
 <!-- Constraints -->
 
 <!-- Drop resource refs that refer to dropped resources -->
 <xsl:variable name="dropped_resource_refs"
               select="//resource_ref[@id = $dropped_resources/@id]"/>
 
 <xsl:template match="resource_ref">
     <xsl:if test="count(.|$dropped_resource_refs)
                   != count($dropped_resource_refs)">
         <xsl:call-template name="identity"/>
     </xsl:if>
 </xsl:template>
 
 <!-- Drop resource sets that would become empty -->
 <xsl:variable name="dropped_resource_sets"
               select="//resource_set
                       [count(resource_ref|$dropped_resource_refs)
                        = count($dropped_resource_refs)]"/>
 
 <xsl:template match="resource_set">
     <xsl:if test="count(.|$dropped_resource_sets)
                   != count($dropped_resource_sets)">
         <xsl:call-template name="identity"/>
     </xsl:if>
 </xsl:template>
 
 <!-- Drop constraints that would contain no valid resource references -->
 <xsl:template match="rsc_location|rsc_ticket">
     <xsl:choose>
         <xsl:when test="@rsc = $dropped_resources/@id"/>
 
         <!-- The constraint contained resource sets, and they're all dropped -->
         <xsl:when test="resource_set
                         and (count(resource_set|$dropped_resource_sets)
                              = count($dropped_resource_sets))"/>
 
         <xsl:otherwise>
             <xsl:call-template name="identity"/>
         </xsl:otherwise>
     </xsl:choose>
 </xsl:template>
 
 <xsl:template match="rsc_colocation">
     <xsl:choose>
         <xsl:when test="@rsc = $dropped_resources/@id"/>
         <xsl:when test="@with-rsc = $dropped_resources/@id"/>
         <xsl:when test="resource_set
                         and (count(resource_set|$dropped_resource_sets)
                              = count($dropped_resource_sets))"/>
         <xsl:otherwise>
             <xsl:call-template name="identity"/>
         </xsl:otherwise>
     </xsl:choose>
 </xsl:template>
 
 <xsl:template match="rsc_order">
     <xsl:choose>
         <xsl:when test="@first = $dropped_resources/@id"/>
         <xsl:when test="@then = $dropped_resources/@id"/>
         <xsl:when test="resource_set
                         and (count(resource_set|$dropped_resource_sets)
                              = count($dropped_resource_sets))"/>
         <xsl:otherwise>
             <xsl:call-template name="identity"/>
         </xsl:otherwise>
     </xsl:choose>
 </xsl:template>
 
 </xsl:stylesheet>
diff --git a/xml/upgrade-3.10-common.xsl b/xml/upgrade-3.10-common.xsl
index 0bda64141c..26e1f0a06f 100644
--- a/xml/upgrade-3.10-common.xsl
+++ b/xml/upgrade-3.10-common.xsl
@@ -1,107 +1,124 @@
 <?xml version="1.0" encoding="UTF-8"?>
 
 <!--
  Use comments liberally as future maintainers may be unfamiliar with XSLT.
  -->
 
 <!--
  upgrade-3.10-common.xsl
 
  This stylesheet is intended to be imported by all other stylesheets in the
  upgrade-3.10-* pipeline. It provides variables and templates that are used by
  multiple stylesheets.
 
  This file should not contain any templates with a match attribute.
 
  Assumptions:
  * The input XML validates against the pacemaker-3.10.rng schema.
  * No element of the input XML contains an id attribute whose value begins with
    "pcmk__3_10_upgrade-". This allows us to generate new IDs without fear of
    conflict. However, the schema does not enforce this assumption.
  * For attributes of type IDREF, the referenced element is of the correct type.
    For example, the rsc attribute in a constraint refers to a resource element
    (primitive, group, clone, bundle). The schema cannot enforce this assumption;
    it requires only that each IDREF refer to a valid ID. As a result, the result
    of our transformation pipeline may fail to validate if IDREFs refer to
    unexpected element types.
 
  @TODO Try to clean up IDREFs to unexpected element types when the referenced
  elements are removed.
  -->
 
 <xsl:stylesheet version="1.0"
                 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
 <!-- Strip whitespace-only text nodes but indent output -->
 <xsl:strip-space elements="*"/>
 <xsl:output encoding="UTF-8" indent="yes" omit-xml-declaration="yes"/>
 
 <!-- Prefix for auto-generated IDs -->
 <xsl:variable name="upgrade_prefix" select="'pcmk__3_10_upgrade-'"/>
 
 <!--
  Modified identity transformation. Copy everything unaltered by default, but set
  the "original" attribute based on the "original" template param.
 
  "original" is a temporary attribute to indicate that an element existed in the
  input XML. It's not allowed by the schema for any element, so we don't have to
  worry about conflicts.
 
  The first step in the upgrade pipeline is to resolve id-ref attributes (type
  IDREF) to id attributes (type ID). We do this as follows. For each element with
  an id-ref attribute, replace that element with a deep copy of the referenced
  element. Set the "original" attribute to 0 in the copy.
 
  At the end of the upgrade pipeline, we convert back to references as follows.
  For each element with an id attribute and with the "original" attribute either
  unset or set to 0:
  * If there is another element with the same id value that either occurs before
    the current element or has original="1", convert the current element back to
    a reference with only the id-ref attribute.
  * Otherwise, drop the "original" attribute and leave the rest of the current
    element's attributes and descendants unchanged (except for converting
    descendants back to references if needed).
 
  Notes:
  * We resolve all attributes named id-ref (which are of type IDREF). We do not
    resolve all attributes of type IDREF. We resolve only in the places where
    either a definition (with id) or a reference (with id-ref) would validate
    against the pacemaker-3.10 schema (ignoring ID uniqueness requirements after
    resolution).
  * If the "original" attribute is unset for an element, the end of the
    transformation pipeline treats the element as if it had original="0".
  * By default, if the "original" param is set, then it's passed down with the
    same value for all descendants.
  -->
 
 <!--
  Identity transformation, optionally setting the "original" attribute
 
  Params:
  * original: Boolean (1/0) indicating whether an element was part of the
              original input XML. If set and this is an element node, the param
              is used as the value for the "original" attribute for this element
              and its descendants.
  -->
 <xsl:template name="identity">
     <xsl:param name="original"/>
 
     <xsl:copy>
         <!-- All existing attributes -->
         <xsl:apply-templates select="@*"/>
 
         <xsl:if test="self::* and $original">
             <!-- Set "original" attribute for element nodes -->
             <xsl:attribute name="original">
                 <xsl:value-of select="$original"/>
             </xsl:attribute>
         </xsl:if>
 
         <!-- All nodes, passing down $original value recursively -->
         <xsl:apply-templates select="node()">
             <xsl:with-param name="original" select="$original"/>
         </xsl:apply-templates>
     </xsl:copy>
 </xsl:template>
 
+<!--
+ Outputs a warning message
+
+ Output a message with the prefix "WARNING: ". This directs Pacemaker's XSLT
+ error handler to strip the prefix and log the message at warning level.
+
+ Params:
+ * msg: Message to output
+ -->
+<xsl:template name="warning">
+    <xsl:param name="msg"/>
+
+    <xsl:message>
+        <xsl:value-of select="concat('WARNING: ', $msg)"/>
+    </xsl:message>
+</xsl:template>
+
 </xsl:stylesheet>